// A background subtraction class 
// (c) Andrew Senior 2006  http://www.andrewsenior.com 
// Preserve this header when redistributing. 

class PBGS
{
  float  [] m_Background;  // The background model has to be float because of quantization effects
  PImage    m_Difference;
  float     m_fBlend=0.99;
  float     m_fComp=1-m_fBlend;
  int m_iWidth;
  int m_iHeight;
  
  // Create the background model to look like the start frame
  PBGS(PImage I)
    {
      m_iWidth=I.width;
      m_iHeight=I.height;
      m_Background=new float[I.width* I.height*3];
      m_Difference=new PImage(I.pixels, I.width, I.height, RGB);
      Set(I);
    }
    
  // Set the background image to the given image
  void Set(PImage I)
  {
    for(int i=0; i<I.width*I.height; i++)
      {
        color iP=I.pixels[i];
        m_Background[i*3]=red(iP);
        m_Background[i*3+1]=green(iP);
        m_Background[i*3+2]=blue(iP);
      }
  }
  // Put the difference in the display buffer
  void PutDifference()
  {
    PImOps.Put(m_Difference);
  }
  
  // Put the background in the display buffer
  void PutBackground()
  {
      for(int i=0; i<m_iWidth*m_iHeight; i++)
      {
        pixels[i]=color(m_Background[i*3], m_Background[i*3+1], m_Background[i*3+2]); 
      }
  }
  
  
  // update the model and compute the difference
    void Update(PImage I)
    {
     m_Difference=new PImage(I.pixels, I.width, I.height, RGB);
     for(int i=0; i<I.width*I.height; i++)
      {
        color iP=I.pixels[i];
      m_Background[i*3]  =m_Background[i*3]*  m_fBlend +m_fComp*red(iP);
      m_Background[i*3+1]=m_Background[i*3+1]*m_fBlend +m_fComp*green(iP);
      m_Background[i*3+2]=m_Background[i*3+2]*m_fBlend +m_fComp*blue(iP);
      m_Difference.pixels[i]=color(abs(m_Background[i*3]-red(iP)), abs(m_Background[i*3+1]-green(iP)), abs(m_Background[i*3+2]-blue(iP))); 
      }
      PImOps.Threshold(m_Difference, 30);
      PImage T=new PImage(m_Difference.width, m_Difference.height);
      PImOps.Copy(T, m_Difference);
      //PImOps.MorphClose(T, m_Difference);
      pconcomps  pcc=new pconcomps();
      pcc.Compute(m_Difference);
      pcc.RemoveSmall(18);
      pcc.SetImage(m_Difference);
    } 
}